[WIP 96%] Mon premier pincab : transfomation zaccaria

/*
  SmartShow AirPixel ONE - Single Universe ArtNet to WS2812 Driver - For Wemos D1
  You can set the Device IP, and universe number below
  Works perfectly with Jinx LED software
 */

#include <ESP8266WiFi.h>
#include <WiFiUdp.h>

#define WSout 5  // Pin D1
#define WSbit (1<<WSout)

// ARTNET CODES
#define ARTNET_DATA 0x50
#define ARTNET_POLL 0x20
#define ARTNET_POLL_REPLY 0x21
#define ARTNET_PORT 6454
#define ARTNET_HEADER 17

WiFiUDP udp;

uint8_t uniData[514];
uint16_t uniSize;
uint8_t hData[ARTNET_HEADER + 1];
uint8_t net = 0;
uint8_t universe = 0;
uint8_t subnet = 0;

const char* ssid    = "XXXXXX";
const char* password = "XXXXXXXXXXXXXX";

IPAddress local_ip(192, 168, 4, 123);
IPAddress gateway_ip(192, 168, 4, 254);
IPAddress subnet_ip(255, 255, 255, 0);

void setup() {
        Serial.begin(115200);
        delay(10);
        Serial.println();
        Serial.println();
        Serial.print("Connecting to ");
        Serial.println(ssid);

        WiFi.begin(ssid, password);
        WiFi.config(local_ip, gateway_ip, subnet_ip);

        while (WiFi.status() != WL_CONNECTED) {
                delay(500);
                Serial.print(".");
        }

        udp.begin(ARTNET_PORT); // Open ArtNet port

        Serial.println("");
        Serial.println("WiFi connected");
        Serial.println("IP address: ");
        Serial.println(WiFi.localIP());

        pinMode(WSout, OUTPUT);
}



void ICACHE_FLASH_ATTR sendWS() {
        uint32_t writeBits;
        uint8_t bitMask, time;
        os_intr_lock();
        for (uint16_t t = 0; t < uniSize; t++) { // outer loop counting bytes
                bitMask = 0x80;
                while (bitMask) {
                        // time=0ns : start by setting bit on
                        time = 4;
                        while (time--) {
                                WRITE_PERI_REG( 0x60000304, WSbit ); // do ON bits // T=0
                        }
                        if ( uniData[t] & bitMask ) {
                                writeBits = 0; // if this is a '1' keep the on time on for longer, so dont write an off bit
                        }
                        else {
                                writeBits = WSbit; // else it must be a zero, so write the off bit !
                        }
                        time = 4;
                        while (time--) {
                                WRITE_PERI_REG( 0x60000308, writeBits ); // do OFF bits // T='0' time 350ns
                        }
                        time = 6;
                        while (time--) {
                                WRITE_PERI_REG( 0x60000308, WSbit ); // switch all bits off  T='1' time 700ns
                        }
                        // end of bite write time=1250ns
                        bitMask >>= 1;
                }
        }
        os_intr_unlock();
}

void loop() {
        if (udp.parsePacket()) {
                Serial.print("Arnet packet :)");
                udp.read(hData, ARTNET_HEADER + 1);
                if ( hData[0] == 'A' && hData[1] == 'r' && hData[2] == 't' && hData[3] == '-' && hData[4] == 'N' && hData[5] == 'e' && hData[6] == 't') {
                        if ( hData[8] == 0x00 && hData[9] == ARTNET_DATA && hData[15] == net ) {
                                if ( hData[14] == (subnet << 4) + universe ) { // UNIVERSE
                                        uniSize = (hData[16] << 8) + (hData[17]);
                                        udp.read(uniData, uniSize);


                                      Serial.print("hData :");
                                        for (int i=0;i<18;i++)
                                          Serial.print(hData[i]);
                                        Serial.println("");
                                        /*Serial.print("uniData :");
                                        for (int i=0;i<514;i++)
                                          Serial.print(uniData[i]);
                                        Serial.println("");
                                        */

                                        Serial.print("ArtNet packet RX Uni 0 - size:");
                                        Serial.println(uniSize);
                                        sendWS();
                                }
                        } // if Artnet Data
                }
        }
}

#include <Adafruit_Sensor.h>
#include "DHT.h"
#define DHTPIN  2
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE); //déclaration du capteur

int pwmPin     = 3; // digital pin 3
int oldfanspeed = 0;

#define FAN1 4 // VENTILO CENTRAL (INJECTION)
#define FAN2 5 // VENTILO ARRIERE (EXTRACTION)
#define FAN3 6
#define FAN4 7

#define ON HIGH
#define OFF LOW

long previousMillis = 0;
long interval = 300000;

void setup()
{
        /* Initialisation du port série */
        Serial.begin(115200);
        dht.begin();
        // generate 25kHz PWM pulse rate on Pin 3
        pinMode(pwmPin, OUTPUT); // OCR2B sets duty cycle
        // Set up Fast PWM on Pin 3
        TCCR2A = 0x23; // COM2B1, WGM21, WGM20
        // Set prescaler
        TCCR2B = 0x0A; // WGM21, Prescaler = /8
        // Set TOP and initialize duty cycle to zero(0)
        OCR2A = 79; // TOP DO NOT CHANGE, SETS PWM PULSE RATE
        OCR2B = 0; // duty cycle for Pin 3 (0-79) generates 1 500nS pulse even when 0 :
        // Initialisation des ventilateurs
        setFanSpeed(0);
        setFanSpeed(79);
        setFanSpeed(0);

        //
        pinMode(FAN1, OUTPUT);
        pinMode(FAN2, OUTPUT);
        pinMode(FAN3, OUTPUT);
        pinMode(FAN4, OUTPUT);
        //
  /*
        for(int i=FAN1; i<=FAN4; i++) {
                digitalWrite(i,ON);   // Turns ON Relays 1
                delay(200);
        }
        delay(2000);
  */
        for(int i=FAN1; i<=FAN4; i++) {
                delay(200);
                digitalWrite(i,OFF); // Turns Relay Off
        }
}

/**
   speed vitesse (0-79)
 */
void setFanSpeed(int speed) {
        OCR2B = speed;
        delay(200);
}

void loop()
{
        /*        unsigned int x;
                // ramp up fan speed by increasing duty cycle every 200mS, takes 16 seconds
                for(x = 0; x < 80; x++) {
                        OCR2B = x; // set duty cycle
                        delay(200);
                }
         */

        // Lecture du taux d'humidité
        float h = dht.readHumidity();
        // Lecture de la température en Celcius
        float t = dht.readTemperature();
        // Stop le programme et renvoie un message d'erreur si le capteur ne renvoie aucune mesure
        if (isnan(h) || isnan(t)) {
                Serial.println("Echec de lecture !");
                return;
        }
        Serial.print("Humidite: ");
        Serial.print(h);
        Serial.print(" %\t");
        Serial.print("Temperature: ");
        Serial.print(t);
        Serial.println(" *C ");

        // FAN speed 25C=>0 40=>80
        float fanspeedt = ((t - 25)/15)*80;
        int fanspeed = (int)fanspeedt;
        if (fanspeed < 0)
                fanspeed = 0;
        if (fanspeed > 79)
                fanspeed = 79;
        if (oldfanspeed != fanspeed) {
                Serial.print("FAN SPEED : "); Serial.println(fanspeed);
                setFanSpeed(fanspeed);
                oldfanspeed = fanspeed;
        }

        unsigned long currentMillis = millis();

        if (t>25){
          previousMillis = currentMillis;
          for(int i=FAN1; i<=FAN4; i++) {
                  delay(200);
                  digitalWrite(i,ON); // Turns Relay Off
          }
        }

        if(currentMillis - previousMillis > interval) {
          for(int i=FAN1; i<=FAN4; i++) {
                  delay(200);
                  digitalWrite(i,OFF); // Turns Relay Off
          }
        }

        delay(10000);
}